すぱんだの解説

・少し進んだところ スタートしてから3画面ほど進んだところです。 背景として建物と花壇が、前景は屋台や銅像です。 小さな敵キャラとして、風船が浮かんでいます。

[戻る]

・現在の状況

・開発中の画面

・スタート画面 スタート直後の画面です。 敵キャラがまだ作っていないので、 主人公のカンカンを表示しています。 宙返りしている方が敵キャラです。 リポビタンDは小さな敵キャラです。

・マップに配置した敵を表示

・敵の種類

[戻る]

・解説

・CG-RAM関係の初期化

set_CGRAM:
	php
	off16a
	sep	#$20
;	CG-RAMのアドレス割り当て
	lda	#$09			;MODE=1 + BG3最優先
	sta	$2105			;BGMODE

	lda	#$07			;%0000011(OBJ 16×16)
	sta	$2101			;OBJSEL

	lda	#>BG1SC0+1
	sta	$2107			;BG1SC
	lda	#>BG2SC0+1
	sta	$2108			;BG2SC
	lda	#>BG3SC0
	sta	$2109			;BG3SC
	sta	$210a			;BG4SC(BGMODE=1では存在しない)

	lda	#(>BG2CHR & $f0) | ((>BG1CHR & $f0)>>4)
	sta	$210b			;BG12NBA
	lda	#(>BG3CHR & $f0)>>4
	sta	$210c			;BG34NBA

	lda	#$80			;address +1 at $2119
	sta	$2115			;VMAINC

	lda	#%00010111
	sta	$212c			;TM(メイン画面)
	sta	$212d			;TS(サブ画面)
	plp
	rts

・当たり判定

atari:
	on16a
	on16i
	rep	#$30

	ldx	p_action		;動作(アクション)
	lda	tableACT,x		;現在の動作(アクション)データのアドレス

	ldx	p_pose			;何番目のポーズか
	clc
	adc	table48,x		;値を48倍するテーブルを加算
	tax				;x=現在のポーズデータ

	lda	pose_data,x
	bit	#$0100			;当判不要のキャラだった
	beq	_exit

	and	#$00ff
	clc
	adc	base_px
	clc
	adc	#16			;前方への攻撃なので余分に+16
	sta	temp_px

	lda	pose_data+1,x		;ポーズ.y
	and	#$00ff
	clc
	adc	base_py
	sta	temp_py

	ldx	#TEKI*4-4
_loop:
	lda	teki_x,x
	cmp	temp_px
	bcs	_next			;敵.x >= 当判.x
	clc
	adc	#16+16			;OBJの大きさ+α
	cmp	temp_px
	bcc	_next			;敵.x+α < 当判.x

	off16a
	sep	#$20
	lda	teki_y,x
	cmp	temp_py
	bcs	_next
	clc
	adc	#16+8			;OBJの大きさ+α
	cmp	temp_py
	bcc	_next

	on16a
	rep	#$20
;当たった敵は右に少し動くことにした
	lda	teki_x,x
	clc
	adc	#8
	sta	teki_x,x

_next:
	on16a
	rep	#$20
	dex
	dex
	dex
	dex
	bpl	_loop
_exit:
	rts

[戻る]

・とにかく遊ぼう

・ダウンロード

・遊びかた

[戻る]